﻿Shader "VREPG/Image Sequence Animation" {
	Properties{
		_Color("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex("Image Sequence", 2D) = "white" {}
		_HorizontalNumber("Horizontal Number", Float) = 4
		_VerticalNumber("Vertical Number", Float) = 4
		_Speed("Speed", Range(1, 100)) = 30
	}

	SubShader {
		Tags {"Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent"}

		Pass {
			Tags { "LightMode" = "ForwardBase" }

			ZWrite Off
			Blend SrcAlpha OneMinusSrcAlpha

			CGPROGRAM

			#pragma vertex vert  
			#pragma fragment frag

			#include "UnityCG.cginc"

			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			float _HorizontalNumber;
			float _VerticalNumber;
			float _Speed;

			struct a2v {
				float4 vertex : POSITION;
				float2 texcoord : TEXCOORD0;
			};
			struct v2f {
				float4 pos : SV_POSITION;
				float2 uv : TEXCOORD0;
			};

			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				return o;
			}

			fixed4 frag(v2f i) : SV_Target {
				float time = floor(_Time.y * _Speed);
				float row = floor(_Time.y * _Speed / _HorizontalNumber);
				float column = time - row * _HorizontalNumber;

				half2 uv = i.uv + half2(column, -row);
				uv.x /= _HorizontalNumber;
				uv.y /= _VerticalNumber;
				fixed4 c = tex2D(_MainTex, uv);
				c.rgb *= _Color;

				return c;
			}

			ENDCG
		}
	}
	FallBack "Transparent/VertexLit"
}
