/*
 * Copyright 2018 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import gradlebuild.basics.PublicApi
import gradlebuild.kotlin.tasks.ParameterNamesIndex

plugins {
    id("gradlebuild.module-identity")
    java
}

val main = sourceSets.main.get()
val parameterNamesIndex by tasks.registering(ParameterNamesIndex::class) {
    sources.from(
        main.allJava.matching {
            include(PublicApi.includes)
            exclude(PublicApi.excludes)
        }
    )
    classpath.from(main.compileClasspath)
    classpath.from(tasks.named<JavaCompile>("compileJava"))
    destinationFile.set(
        project.layout.buildDirectory.file(moduleIdentity.baseName.map { "generated-resources/$it-parameter-names/$it-parameter-names.properties" })
    )
}

tasks.withType<GroovyCompile>() {
    if (name == "compileGroovy") {
        val compileGroovy = this
        parameterNamesIndex.configure {
            classpath.from(compileGroovy)
        }
    }
}

main.output.dir(
    parameterNamesIndex.map { it.destinationFile.get().asFile.parentFile }
)
