# Java Library Publishing Sample

version 6.2.2

- Groovy DSL

- Kotlin DSL

| You can open this sample inside an IDE using the IntelliJ native importer or Eclipse Buildship.

This sample shows how to publish a Java library to a repository. The library has no dependencies and the build has minimal configuration.

build.gradle

    plugins {
        id 'java-library'
        id 'maven-publish'
    }

    version = '1.0.2'
    group = 'org.gradle.sample'

    publishing {
        publications {
            library(MavenPublication) {
                from components.java
            }
        }
        repositories {
            maven {
                url = uri("${buildDir}/publishing-repository")
            }
        }
    }

build.gradle.kts

    plugins {
        `java-library`
        `maven-publish`
    }

    version = "1.0.2"
    group = "org.gradle.sample"

    publishing {
        publications {
            create<MavenPublication>("library") {
                from(components.getByName("java"))
            }
        }
        repositories {
            maven {
                url = uri("${buildDir}/publishing-repository")
            }
        }
    }

To publish the library:

    $ ./gradlew publish

    BUILD SUCCESSFUL in 1s
    4 actionable tasks: 4 executed
    $ tree build/publishing-repository
    build/publishing-repository/
    └── org
        └── gradle
            └── sample
                └── library-publishing
                    ├── 1.0.2
                    │   ├── library-publishing-1.0.2.jar
                    │   ├── library-publishing-1.0.2.jar.md5
                    │   ├── library-publishing-1.0.2.jar.sha1
                    │   ├── library-publishing-1.0.2.jar.sha256
                    │   ├── library-publishing-1.0.2.jar.sha512
                    │   ├── library-publishing-1.0.2.module
                    │   ├── library-publishing-1.0.2.module.md5
                    │   ├── library-publishing-1.0.2.module.sha1
                    │   ├── library-publishing-1.0.2.module.sha256
                    │   ├── library-publishing-1.0.2.module.sha512
                    │   ├── library-publishing-1.0.2.pom
                    │   ├── library-publishing-1.0.2.pom.md5
                    │   ├── library-publishing-1.0.2.pom.sha1
                    │   ├── library-publishing-1.0.2.pom.sha256
                    │   └── library-publishing-1.0.2.pom.sha512
                    ├── maven-metadata.xml
                    ├── maven-metadata.xml.md5
                    ├── maven-metadata.xml.sha1
                    ├── maven-metadata.xml.sha256
                    └── maven-metadata.xml.sha512

    5 directories, 20 files

For more information, see Java Library Plugin reference chapter.