/*
 * Copyright 2014 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */



package org.gradle.api.internal.tasks.compile.incremental

import org.gradle.api.internal.file.FileOperations
import org.gradle.api.internal.tasks.compile.JavaCompileSpec
import org.gradle.api.tasks.util.PatternSet
import spock.lang.Specification
import spock.lang.Subject

class IncrementalCompilationInitializerTest extends Specification {

    def fileOperations = Mock(FileOperations)
    @Subject initializer = new IncrementalCompilationInitializer(fileOperations)

    def "prepares patterns"() {
        PatternSet classesToDelete = Mock(PatternSet)
        PatternSet sourceToCompile = Mock(PatternSet)

        when:
        initializer.preparePatterns(["com.Foo", "Bar"], classesToDelete, sourceToCompile)

        then:
        1 * classesToDelete.include('com/Foo.class')
        1 * classesToDelete.include('com/Foo$*.class')
        1 * classesToDelete.include('Bar.class')
        1 * classesToDelete.include('Bar$*.class')

        1 * sourceToCompile.include('Bar.java')
        1 * sourceToCompile.include('com/Foo.java')

        0 * _
    }

    def "does not prepare patterns when stale classes empty"() {
        when: initializer.preparePatterns([], Mock(PatternSet), Mock(PatternSet))
        then: thrown(AssertionError)
    }

    def "configures empty source when stale classes empty"() {
        def compileSpec = Mock(JavaCompileSpec)
        when: initializer.initializeCompilation(compileSpec, [])
        then:
        1 * compileSpec.setSource { it.files.empty }
        0 * _
    }
}
