/*
 * Copyright 2011 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package org.gradle.initialization

import org.gradle.api.artifacts.ResolvableDependencies
import org.gradle.logging.ProgressLoggerFactory
import spock.lang.Specification
import org.gradle.logging.ProgressLogger

class DependencyResolutionLoggerTest extends Specification {
    final ProgressLoggerFactory progressLoggerFactory = Mock()
    final ResolvableDependencies dependencies = Mock()
    final ProgressLogger progressLogger = Mock()
    final DependencyResolutionLogger logger = new DependencyResolutionLogger(progressLoggerFactory)

    def "generates progress logging events as dependency sets are resolved"() {
        when:
        logger.beforeResolve(dependencies)

        then:
        1 * progressLoggerFactory.newOperation(DependencyResolutionLogger) >> progressLogger
        1 * progressLogger.setDescription("Resolve ${dependencies}")
        1 * progressLogger.setShortDescription("Resolving ${dependencies}")
        1 * progressLogger.started()
        0 * progressLogger._

        when:
        logger.afterResolve(dependencies)

        then:
        1 * progressLogger.completed()
        0 * progressLogger._
    }
}
