/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */
package groovy

import gls.CompilableTestSupport

final class InterfaceTest extends CompilableTestSupport {

    void testGenericsInInterfaceMembers() {
        // control
        shouldCompile '''
            interface I {
                def <T>                      T m1(T x)
                def <U extends CharSequence> U m2(U x)
                def <V, W>                   V m3(W x)
                def <N extends Number>    void m4(   )
            }
        '''
        // erroneous
        shouldNotCompile 'interface I { def <?> m(x) }'
        shouldNotCompile 'interface I { def <? extends CharSequence> m(x) }'
    }

    // GROOVY-5106
    void testReImplementsInterface1() {
        def err = shouldFail '''
            interface I<T> {}
            interface J<T> extends I<T> {}
            class X implements I<String>, J<Number> {}
        '''
        assert err.contains('The interface I cannot be implemented more than once with different arguments: I<java.lang.String> (via X) and I<java.lang.Number> (via J)')
    }

    // GROOVY-5106
    void testReImplementsInterface2() {
        def err = shouldFail '''
            interface I<T> {}
            class X implements I<Number> {}
            class Y extends X implements I<String> {}
        '''
        assert err.contains('The interface I cannot be implemented more than once with different arguments: I<java.lang.String> (via Y) and I<java.lang.Number> (via X)')
    }

    // GROOVY-11707
    void testReImplementsInterface3() {
        shouldCompile '''
            abstract class A implements Comparable {
            }
            abstract class B extends A implements Comparable {
            }
        '''
    }

    // GROOVY-11736
    void testReImplementsInterface4() {
        def err = shouldFail '''
            abstract class A implements Comparable<Object> {
            }
            abstract class B extends A implements Comparable {
            }
        '''
        assert err.contains('The interface Comparable cannot be implemented more than once with different arguments: java.lang.Comparable (via B) and java.lang.Comparable<java.lang.Object> (via A)')
    }

    // GROOVY-11803
    void testDefaultInterfaceMethod() {
        assertScript '''
            interface Foo {
                default int barSize() {
                    return bar.size()
                }
                String getBar()
            }
            class Baz implements Foo {
                final String bar = 'BAR'
            }

            assert new Baz().barSize() == 3
        '''
        for (kind in ['default','private','static']) {
            assertScript """
                interface Foo {
                    default int barSize() {
                        return bar.size()
                    }
                    $kind String getBar() {
                        return 'fizzbuzz'
                    }
                }
                class Baz implements Foo {
                }

                assert new Baz().barSize() == 8
            """
        }
    }

    // GROOVY-10060
    void testPrivateInterfaceMethod() {
        assertScript '''
            interface Foo {
                default foo() { Foo.this.hello('Foo#foo') }
                @groovy.transform.CompileStatic
                default baz() { hello('Foo#baz') }
                private hello(where) { "hello from $where"}
            }

            class Parent {
                public bar() {
                    hello 'Parent#bar'
                }
                private hello(where) { "howdy from $where"}
            }

            class Impl1 extends Parent implements Foo {
                def baz() { 'hi from Impl1#baz' }
            }

            class Impl2 extends Parent implements Foo {
            }

            def impl1 = new Impl1()
            assert impl1.baz() == 'hi from Impl1#baz'
            assert impl1.bar() == 'howdy from Parent#bar'
            assert impl1.foo() == 'hello from Foo#foo'
            def impl2 = new Impl2()
            assert impl2.baz() == 'hello from Foo#baz'
            assert impl2.bar() == 'howdy from Parent#bar'
            assert impl2.foo() == 'hello from Foo#foo'
        '''
    }

    // GROOVY-11237
    void testPublicStaticInterfaceMethod() {
        assertScript '''import static groovy.test.GroovyAssert.shouldFail
            interface Foo {
                static hello(where) { "hello $where" }
                static String BAR = 'bar'
                       String BAZ = 'baz' // implicit static
            }

            assert Foo.hello('world') == 'hello world'
            assert Foo.BAR == 'bar'
            assert Foo.BAZ == 'baz'

            shouldFail(MissingMethodException) {
                Foo.getBAR()
            }
            shouldFail(MissingMethodException) {
                Foo.getBAZ()
            }
        '''
    }

    // GROOVY-11758
    void testSuperClassFinalMethodAndInterfaceMethod() {
        def err = shouldNotCompile '''
            interface A {
                def m()
            }
            class B {
                protected final m() {
                }
            }
            class C extends B implements A {
            }
        '''
        assert err =~ /inherited final method m\(\) from B cannot shadow the public method in A/
    }

    // GROOVY-11753
    void testSuperClassCovariantOfParameterizedInterface() {
        assertScript '''
            class A extends B {
            }
            class B implements C<String> {
                static class NestMate {
                }
                @Override
                void p(String s) {
                    print(s)
                }
            }
            interface C<T> {
                void p(T t)
            }

            new A().p("")
        '''
    }
}
