/*
 *  Licensed to the Apache Software Foundation (ASF) under one
 *  or more contributor license agreements.  See the NOTICE file
 *  distributed with this work for additional information
 *  regarding copyright ownership.  The ASF licenses this file
 *  to you under the Apache License, Version 2.0 (the
 *  "License"); you may not use this file except in compliance
 *  with the License.  You may obtain a copy of the License at
 *
 *    https://www.apache.org/licenses/LICENSE-2.0
 *
 *  Unless required by applicable law or agreed to in writing,
 *  software distributed under the License is distributed on an
 *  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 *  KIND, either express or implied.  See the License for the
 *  specific language governing permissions and limitations
 *  under the License.
 */
package spec

import page.role.RoleCreatePage
import page.role.RoleEditPage
import page.role.RoleSearchPage

import grails.testing.mixin.integration.Integration

@Integration
class RoleSpec extends AbstractSecuritySpec {

	void testFindAll() {
		when:
		def page = to(RoleSearchPage)

		then:
		page.assertNotSearched()

		when:
		page.submit()
		page = at(RoleSearchPage)

		then:
		waitFor {
			page.assertResults(1, 10, 12)
			pageSource.contains('ROLE_COFFEE')
		}
	}

	void testFindByAuthority() {
		when:
		def page = to(RoleSearchPage).tap {
			search('ad')
		}

		then:
		waitFor {
			page.assertResults(1, 2, 2)
			pageSource.contains('ROLE_ADMIN')
			pageSource.contains('ROLE_INSTEAD')
		}
	}

	void testUniqueName() {
		when:
		to(RoleCreatePage).with {
			create('ROLE_ADMIN')
		}

		then:
		waitFor { pageSource.contains('must be unique') }

	}

	void testCreateAndEdit() {
		given:
		def newName = "ROLE_NEW_TEST${UUID.randomUUID()}"

		// make sure it doesn't exist
		when:
		def page = to(RoleSearchPage).tap {
			search(newName)
		}

		then:
		waitFor { page.assertNoResults() }

		// create
		when:
		via(RoleCreatePage).with {
			create(newName)
		}
		page = at(RoleEditPage)

		then:
		page.authority.text == newName

		// edit
		when:
		page.update("${newName}_new")
		page = at(RoleEditPage)

		then:
		waitFor { page.authority.text == "${newName}_new" }

		// delete
		when:
		page.delete()
		page = at(RoleSearchPage)

		and:
		page.search("${newName}_new")
		page = at(RoleSearchPage)

		then:
		waitFor { page.assertNoResults() }
	}
}
